***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Aug 27, 2021                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJQ1916   D   G   S
*****param & model definition***
.model  dmos  nmos(
+    l = 1e-6		   w = 1e-6		level = 3
+ kappa = 5e-2
+  vto = 0.65		  kp = 5.2)
.model  dds   d(
+   is = 2.579e-9	   n = 1.205		   rs = 5.051e-1		ikf = 8.247e-3
+   eg = 6.600e-1	trs1 = 1.000e-3)
.model  dbody d(
+   is = 2.579e-9	   n = 1.205		   rs = 5.051e-1		ikf = 8.247e-3
+   eg = 6.600e-1	trs1 = 1.000e-3
+  cjo = 8.835e-12	   m = 4.426e-1		   vj = 3.905e-1
+   bv = 22		 ibv = 250e-6		 tbv1 = 9.049e-4		tt = 25n)
.model  inter  nmos(
+  vto = 0		  kp = 10		level = 1)
.model  dgd    d(
+  cjo = 4.413e-11	  m = 4.421e-1		   vj = 3.905e-1)
.param
+  cgs = 2.174e-9	cgd = 1.827e-10
+   rd = 7.873e-2	 ra = 7.873e-2		 trd1 = 1.034e-2
*****function & circuit***
rg	  G  1t   1
cgs	 1t   3   {cgs}   ;ic = 0
egv	  2t  3   table   {v(1t, S)}
+((0   , 0   ),
+ (1   , 1   ),
+ (2   , 2   ),
+ (2.5 , 2.5 ),
+ (3   , 2.85),
+ (3.5 , 3.2 ),
+ (4   , 3.45),
+ (4.5 , 3.75),
+ (5   , 3.9 ),
+ (6   , 4.2 ),
+ (8   , 4.5 ),
+ (10  , 4.8 )))
egt	  1  2t   value = {1.087e-4*limit(v(2t,3),0,5)*limit((temp-25),-80,125)}
mmain	  2   1   3   3   dmos
rd	  D   4   {rd}    tc = {trd1}
dds	  3   4   dds
dbody	  3   D   dbody
ra	  4   2   {ra}
rs	  3   5   1e-4
ls	  5   S   0.001n
m1	 1t   8   6   6   inter
e1	  8   6   4   1t  2
cgd	  7   4   {cgd}   ;ic = 0
rcgd	  7   4   10meg
dgd	  6   4   dgd
rdgd	  4   6   10meg
m2	  7   9  1t  1t   inter
e2	  9  1t   4  1t   -2
.ends
*$
